Comment
===================================================

DM3 Menu Overlay * CopyRight 1989-90 By Marc Perkel

This is a File Compression Overlay fo DM3. This allows
you to compress marked files.

Note: For self extracting ZIP files you will need PKZIP
version 1.10 or later.

===================================================
EndComment

Var %CompressName %FullCompressName %EchoSt

if DosVersionString >= '3.30'
   %EchoSt = '@Echo Off'
else
   %EchoSt = 'Echo Off'
endif

if ColorScreen
   BoxHeaderColor Yellow Mag
   InverseColor Yellow Mag
   BoxBorderColor LGreen Brown
   BoxInsideColor Grey Brown
else
   BoxHeaderColor Black Grey
   InverseColor Black Grey
   BoxBorderColor White Black
   BoxInsideColor Grey Black
endif

ClearScreenOnExit Off
BlankTime = 10
BlankMessage = 'Executing DM3'

BoxHeader = ' Compress File Menu '
DrawBox 28 7 26 8
TextColor Yellow Brown
ClearLine 205
TextColor Grey Brown
UseArrows
CapsColor Yellow Brown

Writeln
Writeln '  1 ZIP Marked Files'
Writeln '  2 PKARC Marked Files'
Writeln '  3 ICE Marked Files'
Writeln '  4 Self Extract ICE'
Write   '  5 Self Extract ZIP'

OnKey 'E'
  ME %MenuFileName

OnKey '1'
  |FileNameBox
  %EchoSt
  ZIP %CompressName  @%1 ;Note: 2 spaces here causes 1 in batch file
  ZIP -V %CompressName |MORE

OnKey '2'
  |FileNameBox
  %EchoSt
  PKARC A %CompressName  @%1
  PKARC V %CompressName |MORE

OnKey '3'
  |FileNameBox
  %EchoSt
  TYPE %1|DOLIST ICE A %CompressName  @L
  ICE V %CompressName |MORE

OnKey '4'
  |FileNameBox
  |%FullCompressName = %FullCompressName + '.ICE'
  %EchoSt
  TYPE %1|SORT|DOLIST ICE A %CompressName  @L
  ICE S %CompressName
  DEL %FullCompressName

OnKey '5'
  |FileNameBox
  |%FullCompressName = %FullCompressName + '.ZIP'
  %EchoSt
  ZIP %CompressName  @%1
  ZIP2EXE -J %CompressName
  DEL %FullCompressName


Procedure FileNameBox
var Period
  BoxBorderColor LCyan Blue
  BoxInsideColor White Blue
  DrawBox 36 13 35 3
  TextColor White Blue
  Write ' File: '
  %CompressName = Readln
  Period = pos('.',%CompressName)
  if Period > 0 then %CompressName = Left(%CompressName,pred(Period))
  %FullCompressName = %CompressName
EndProc