Comment
=============================================================

Copyright 1996-2000 by Marc Perkel

This program is used to generate a new MarxMenu HTML web pages.

=============================================================
EndComment

var
  Out
  Inp
  Toc
  Line
  Chapter
  ChapterNumber
  ChapterName
  ChapterNameClean
  Catagory
  CatIndex
  Ph
  Pass
  LastCh
  Start
  CodeMode
  Footer
  Title
  BaseDir

Var STime ETime

Include 'g:\banners.inc'

STime = Timer
Main
ETime = Timer
Writeln 'Time: ' (ETime - STime)


Procedure DoChapter
var FileName Ch St P Line

   ReadChapter
   Trim(Chapter)

   FileName = MakeFileName(ChapterNumber)

   FileAssign(Out,BaseDir + FileName)
   FileCreate(Out)

   if Ph >= 3
      St = ChapterNameClean
      while (St > '') and (Left(St,1) < 'A')
         delete(St,1,1)
      endwhile
      Ch = Left(St,1)

      if (Ch = 'A') and (LastCh <> 'A')
         Start
      endif

      if (Ch >= 'A') and Start
         if Ch > LastCh
            Write Ch ' '
            WrToc '<A NAME="' Ch '"></A>'
            WrToc '<BR>'
            WrToc AddLine
            WrToc '<A HREF="#Top">Top</A> - '
            WrToc '<A HREF="marxcat.htm#Top">Categories</A> - '
            WrToc HomePage
            WrToc '<H3><CENTER>- ' Ch ' -</CENTER></H3>  '
            LastCh = Ch
         endif
      endif
   endif

   WrToc '<A NAME="' ChapterNameClean '"></A>'
   WrToc '<A HREF="' MakeFileName(ChapterNumber) '">'
   if Ph >= 3
      WrToc Chapter[1] '</A><BR>'
   else
      WrToc ChapterName '</A><BR>'
   endif

   WriteHeader(Loc Out,ChapterNameClean)
   Indexes
   Wr '<P>' AddLine
   Wr '<H3>' NameColor Chapter[1] '</H3></FONT>'
   delete(Chapter,1,1)

   Substitute(Chapter,'<','&lt;')
   Substitute(Chapter,'>','&gt;')

   Loop Chapter
      Line = LoopVal
      if Line = ''
         Wr '<P>'

      elseif Line StartsWith '..'
         delete(Line,1,2)
         St = UpperCase(NextWordDelim(Line,''))
         if St = 'DOWNLOAD'
            if ExistFile('g:\ctyme\download\share\' + Line)
               Wr '<B>Download:</B>'
               Wr '<A HREF="http://www.ctyme.com/download/share/' Line '">'
               Wr UpperCase(Line) '</A>'
            else
               Writeln 'File ' Line ' missing.'
            endif
         endif

      elseif Line StartsWith ' '
         SetCodeMode On
         if LoopVal contains 'Example:'
            Wr '<FONT COLOR=#6000A0><B><I>Example:</I></B></FONT><BR>'
         else
            Wr LoopVal
         endif

      elseif Line StartsWith 'See Also:'
         SetCodeMode Off

         delete(Line,1,9)
         trim(Line)

         Wr '<TABLE BORDER=1 CELLPADDING=3 CELLSPACING=1>'

         if not (Chapter[LoopIndex-1] StartsWith 'See Also:')
            Wr '<TH><FONT COLOR="#D00040">See Also:</FONT></TH>'
         endif

         while Line > ''
            St = NextWordDelim(Line,',')
            if HashExist(St)
               P = Hash(St)[1]
            else
               Writeln 'Error: See Also [' St '] in ' ChapterNameClean
            endif
            Wr '<TD><A HREF="' MakeFileName(P) '">'
            Wr St '</A></TD>'
         endwhile

         Wr '</TABLE>'

      elseif Line StartsWith 'Category:'
         SetCodeMode Off

         delete(Line,1,9)
         trim(Line)

         Wr '<TABLE BORDER=1 CELLPADDING=3 CELLSPACING=1>'
         Wr '<TH><FONT COLOR="#D00040">Category:</FONT></TH>'

         while Line > ''
            St = NextWordDelim(Line,',')
            Wr '<TD><A HREF="marxcat.htm#' St '">'
            Wr St '</A></TD>'
            AddToCatagory(St,ChapterNameClean)
         endwhile

         Wr '</TABLE>'

      else

      ;- normal line

         SetCodeMode Off
         Wr(Line)
      endif
   EndLoop

   SetCodeMode Off

   Wr '<P>'
   Wr AddLine
   Indexes
   PageFooter
   FileClose(Out)
EndProc


Procedure PageFooter
Var Sponsor, Conf, Mail, Index, Home

   Wr
   Wr '<!-- Bottom Link Start -->'
   Wr
   Wr '<center>'

   Sponsor = 'http://www.ctyme.com/sponsor.htm'
   Conf = 'http://talk.ctyme.com/webx.cgi?13@@.ee6b2b8'
   Mail = 'http://www.ctyme.com/mail.htm'
   Index = 'http://www.ctyme.com/map.htm'
   Home = 'http://www.ctyme.com'

   MyLinks (Sponsor, Conf, Home, Index, Mail)

   Loop MyLinksArray
      Wr LoopVal
   EndLoop

   Wr

   Loop Footer
      Wr LoopVal
   EndLoop

   Wr

;   ModValueClick
;   AddBanner VC

;   AddRandomBanner(SponsorList)

   Wr AddLine
   Wr
   Wr '<!-- Bottom Link End -->'
   Wr ''
   Wr '</BODY>'
   Wr '</HTML>'
EndProc


Procedure AddToCatagory (Cat,Name)
var C
   C = PosInList(Cat,Catagory)
   if C = 0
      AppendArray(Catagory,Cat)
      C = NumberOfElements(Catagory)
   endif

   AppendArray(CatIndex[C],Name)
EndProc


Procedure SetCodeMode (F)
   if F = CodeMode then Return
   if F
     Wr '<PRE>' PreColor
     CodeMode
   else
     Wr '</FONT></PRE>'
     CodeMode Off
   endif
EndProc


Procedure Indexes
var St

   Wr '<TABLE BORDER=1 CELLPADDING=3 CELLSPACING=1>'

   if Ph = 1
      St = 'utiltoc.htm'
   else
      St = 'marxtoc.htm'
   endif

   Wr '<TD>'

   if ChapterNumber > 1
      Wr '<A HREF="' MakeFileName(ChapterNumber-1) '">'
   else
      Wr '<A HREF="St">'
   endif
   Wr '<IMG SRC=http://graphics.ctyme.com/gif/lup.gif BORDER=0 ALT=Prev></A>'

   if EndOfFile(Inp) and ((Ph = 1) or (Ph = 4))
      Wr '<A HREF="' MakeFileName(1) '">'
   else
      Wr '<A HREF="' MakeFileName(ChapterNumber+1) '">'
   endif

   Wr Set[
<IMG SRC=http://graphics.ctyme.com/gif/ldown.gif BORDER=0 ALT=Next></A>
<A HREF=http://www.ctyme.com>
<IMG SRC=http://graphics.ctyme.com/gif/lhome.gif BORDER=0 ALT=Home></A>
<A HREF=http://www.ctyme.com/nsk.htm>
<IMG SRC=http://graphics.ctyme.com/gif/rhome.gif BORDER=0 ALT=Home></A>
</TD><TD>
]

   Wr '<A HREF="' St '#' ChapterNameClean '">

   Wr Set[
Table Of Contents</A>
</TD><TD>
<A HREF="marxcat.htm">
Index</A>
</TD></TABLE>
]

EndProc


Procedure WriteHeader (F, Title)
var St
   FileWriteln(F,'<HTML><HEAD><TITLE>')
   FileWriteln(F,Title,'</TITLE>')

   FileWriteln(F,'<META NAME="Description" CONTENT="')

   FileWriteln(F,Chapter[1])

   Loop 8
      St = Chapter[LoopIndex + 1]
      Trim(St)
      Substitute(St,'"','')
      Substitute(St,'>','')
      Substitute(St,'<','')
      if St > '' then FileWriteln(F,St)
   EndLoop

   FileWriteln(F,'">')

   FileWriteln(F,'<META NAME="Robots" CONTENT="NONE">')

   FileWriteln(F,'</HEAD>')
   FileWriteln(F,'<BODY BGCOLOR="#FFD0A0">')
   FileWriteln(F,'<A NAME="Top">')
   FileWriteln(F,'<CENTER>')
   FileWriteln(F,'<H2>' Title '</H2></CENTER>')
EndProc


Procedure WriteFooter (F)
   FileWriteln(F,Footer)
   FileClose(F)
EndProc


Procedure ReadChapter
var P
   ChapterNumber = ChapterNumber + 1
   delete(Line,1,3)
   P = Pos('.',Line)
   ChapterName = Left(Line,P-1)
   Trim(ChapterName)

   ChapterNameClean = ChapterName
   while pos('--',ChapterNameClean) > 0
      delete(ChapterNameClean,pos('--',ChapterNameClean),2)
   endwhile
   Trim(ChapterNameClean)

   dispose(Chapter)

   while not EndOfFile(Inp)
      Line = FileReadln(Inp)
      if Line StartsWith '.tc'
         Return
      endif
      AppendArray(Chapter,Line)
   endwhile

EndProc


Procedure MakeFileName (N)
var St
   St = Str(N)
   while length(St) < 4
      St = '0' + St
   endwhile
   Return 'doc' + St + '.htm'
EndProc


Procedure DoFile (Phase)
var Ch
   Ph = Phase
   if Phase = 1
      FileAssign(Inp,'BOX.DOC')
      FileOpen(Inp)
   elseif Phase = 2
      FileAssign(Inp,'MARX2A')
      FileOpen(Inp)
   elseif Phase = 3
      FileAssign(Inp,'MARX2B')
      FileOpen(Inp)
   elseif Phase = 4
      FileAssign(Inp,'MARX2C')
      FileOpen(Inp)
   endif

   if Phase = 1
      FileAssign(Toc,BaseDir + 'utiltoc.htm')
      FileCreate(Toc)
      WriteHeader(Loc Toc,'DOS ToolBox * Table of Contents')

      WrToc '<A HREF="marxtoc.htm">'
      WrToc 'MarxMenu Manual</A>'

      WrToc HomePage

   elseif Phase = 2
      FileAssign(Toc,BaseDir + 'marxtoc.htm')
      FileCreate(Toc)
      WriteHeader(Loc Toc,'MarxMenu * Table of Contents')

      WrToc '<A HREF="marxcat.htm">'
      WrToc 'Index</A>'

      WrToc '<A HREF="utiltoc.htm">'
      WrToc 'Dos ToolBox</A>'

      WrToc HomePage

      WrToc '<BR>'
      Loop 26
         Ch = Char(LoopIndex + 64)
         WrToc '<A HREF="#' Ch '">' Ch '</A>'
      EndLoop
      WrToc '<A HREF="http://www.ctyme.com/download/share/mxmenu.zip">'
      WrToc 'Download MarxMenu</A>'
      WrToc '<P>' AddLine
   endif

   if Phase = 3
      while not (Line StartsWith '..')
         Line = FileReadln(Inp)
      endwhile
   elseif Phase = 4

   else
      while Line <> '..html'
         Line = FileReadln(Inp)
      endwhile
   endif

   Line = FileReadln(Inp)

   while not EndOfFile(Inp)
      DoChapter
   endwhile

   FileClose(Inp)

   if (Phase <> 2) and (Phase <> 3)
      WriteFooter(Loc Toc)
   endif

EndProc


Procedure AddToIndex
var Rec
   Rec[1] = ChapterNumber
   Rec[2] = Chapter[1]
   Hash(ChapterNameClean) = Rec
EndProc


Procedure IndexPass
   Pass = 1
   FileAssign(Inp,'BOX.DOC')
   FileOpen(Inp)

   while Line <> '..html'
      Line = FileReadln(Inp)
   endwhile

   Line = FileReadln(Inp)

   while not EndOfFile(Inp)
      ReadChapter
      AddToIndex
   endwhile

   FileClose(Inp)

   FileAssign(Inp,'MARX2A')
   FileOpen(Inp)

   while Line <> '..html'
      Line = FileReadln(Inp)
   endwhile

   Line = FileReadln(Inp)

   while not EndOfFile(Inp)
      ReadChapter
      AddToIndex
   endwhile

   FileClose(Inp)

   FileAssign(Inp,'MARX2B')
   FileOpen(Inp)

   while not (Line StartsWith '..')
      Line = FileReadln(Inp)
   endwhile

   Line = FileReadln(Inp)

   while not EndOfFile(Inp)
      ReadChapter
      AddToIndex
   endwhile

   FileClose(Inp)

   FileAssign(Inp,'MARX2C')
   FileOpen(Inp)

   Line = FileReadln(Inp)

   while not EndOfFile(Inp)
      ReadChapter
      AddToIndex
   endwhile

   FileClose(Inp)
   Pass = 2

EndProc


Procedure Wr ($St)
   FileWriteln(Out,St)
EndProc


Procedure WrToc ($St)
   FileWriteln(Toc,St)
EndProc


Procedure AddLine
   Return '<center><img src=http://graphics.ctyme.com/gif/rbline.gif width="100%"></center><p>'
EndProc


Procedure PreColor
   Return '<FONT COLOR=#008040>'
EndProc


Procedure NameColor
   Return '<FONT COLOR=#E00040>'
EndProc


Procedure HomePage
   Return '<A HREF="http://www.ctyme.com">Home Page</A>'
EndProc


Procedure CreateCatagoryFile
var P Rec

   SortArrayLinked(CatIndex,Catagory)
   Loop CatIndex
      SortArray(LoopVal)
   EndLoop

   FileAssign(Toc,BaseDir + 'marxcat.htm')
   FileCreate(Toc)
   WriteHeader(Loc Toc,'MarxMenu Command Catagories')

   WrToc '<A HREF="marxtoc.htm">'
   WrToc 'Table of Contents</A>'

   WrToc HomePage '<P>'

   WrToc '<TABLE BORDER=6 CELLPADDING=5 CELLSPACING=3 COLS=7>
   WrToc '<TR ALIGN=MIDDLE>'

   Loop Catagory
      if (LoopIndex > 1) and (LoopIndex - 1 mod 7 = 0)
         WrToc '</TR><TR ALIGN=MIDDLE>'
      endif
      WrToc '<TD><A HREF="#' LoopVal '">' LoopVal '</A></TD>'
   EndLoop

   WrToc '</TR>'
   WrToc '</TABLE>'

   Loop CatIndex
      WrToc '<A NAME="' Catagory[LoopIndex] '"></A>'
      WrToc '<P>' AddLine
      WrToc '<H3>' Catagory[LoopIndex] '</H3>'
      Loop LoopVal
         Rec = Hash(LoopVal)
         WrToc '<A HREF="' MakeFileName(Rec[1]) '">' Rec[2] '</A><BR>'
      EndLoop
   EndLoop

   WriteFooter(Loc Toc)

EndProc


Procedure Setup
   StandardIO
   BaseDir = 'r:\nobackup\marxdoc\'
   UpperCaseCompare
   BlankTime = 0

   ReadTextFile 'FOOT.TXT' Footer
   Trim(Footer)
EndProc


Procedure Main
   StandardIO
   Setup
   ChapterNumber = 0
   Writeln 'IndexPass'
   IndexPass
   ChapterNumber = 0
   Writeln 'File 1'
   DoFile(1)
   Writeln 'File 2'
   DoFile(2)
   WrToc AddLine
   Writeln 'File 3'
   DoFile(3)
   Writeln
   Writeln 'File 4'
   DoFile(4)
   Writeln
   Writeln 'Catagories'
   CreateCatagoryFile
EndProc