Comment
==========================================================

Computer Tyme fax menu. This is a client menu that works with
FaxServ.mnu so that the user can send faxes without using the MHS mail
system. It also manages incomming faxes for viewing and printing.

=========================================================
EndComment

;----- Create Variables

Var
  From
  Company
  Department
  FaxTo
  Subject
  Phone
  FileName
  Com
  FaxFile
  FaxDate
  FaxTime
  Compress
  PersonalFax
  NewFaxes
  FaxConnection
  DB


StandardIO

Setup
SendFaxes


;========================================


Procedure SendFaxes
var X
   Loop DB
      X = LoopIndex
      Company = DB[X,1]
      FaxTo = 'News: ' + Company
;      FaxTime = '23:05'
      Phone = DB[X,2]
      Writeln 'Faxing to: ' Company ' at ' Phone
      MailFax
   EndLoop
EndProc


Procedure Setup
;   Compress On
   From = NovFullName
;   Department = 'Political News'
;   Subject = 'Press Release'
   Subject = 'Letter to the Editor'
   FileName = CleanFileName('F:\HOME\MARC\LETTERS\CONG1.')
   ReadAscTextFile(ParamStr(2),DB)
EndProc


Procedure MailFax
var X

   ;MHS Header

   AppendArray(X,'SMF-70')
   AppendArray(X,'FROM: ' + NovLoginName + ' @ CTYME')
   AppendArray(X,'TO: BBS2 @ CTYME')
   AppendArray(X,'')

   ;Information for fax server

   AppendArray(X,'FROM: ' + From)
   if FaxTo > '' then AppendArray(X,'ATTN: ' + FaxTo)
   if Company > '' then AppendArray(X,'COMPANY: ' + Company)
   if Department > '' then AppendArray(X,'DEPT: ' + Department)
   if Subject > '' then AppendArray(X,'SUBJECT: ' + Subject)
   if FaxDate > '' then AppendArray(X,'DATE: ' + FaxDate)
   if FaxTime > '' then AppendArray(X,'TIME: ' + FaxTime)
   if Compress then AppendArray(X,'COMPRESS: ON')
   AppendArray(X,'PHONE: ' + Phone)
   if ExistOnPath(FileName) > ''
      AppendArray(X,'FAXFILE: ' + FileName)
   endif

   Loop Com
      AppendArray(X,Com[LoopIndex])
   EndLoop

   WriteTextFile(MhsSendDirectory + '\' + UniqueFileName,X)
EndProc