Comment
=======================================

VID.MNU Copyright 1992 by Marc Perkel

This menu allows you to set the video mode to anything you want.
You can use it to set advanced VGA modes as well as standard modes.

Usage:
   MARXMENU VID
   MARXMENU VID <mode number>

=======================================
EndComment

if ParamStr(2) > ''
   SetMode(Value(ParamStr(2)))
   exitmenu
endif

Explode Off
BoxBorderColor Green Blue
BoxInsideColor Yellow Blue
BoxHeaderColor White Cyan
InverseColor Yellow Mag

UseArrows
BoxHeader ' * Select Video Menu * '
BoxFooter ' * ESC to Exit * '
DrawBox (ScreenWidth / 2 - 14, ScreenHeight / 2 - 5, 27, 12)

DrawBar
Writeln
Writeln '  1 - Color 80'
Writeln '  2 - BW 80'
Writeln '  3 - Color 43/50'
Writeln '  4 - BW 43/50'
Writeln '  5 - Mono/Herc'
Writeln '  6 - Color 40'
Writeln '  7 - BW 40'
Writeln '  8 - Type in Mode'
DrawBar

OnKey '1'
  |SetMode(CO80)

OnKey '2'
  |SetMode(BW80)

OnKey '3'
  |SetMode(CO80 + 256)

OnKey '4'
  |SetMode(BW80 + 256)

OnKey '5'
  |SetMode(Mono)

OnKey '6'
  |SetMode(CO40)

OnKey '7'
  |SetMode(BW40)

OnKey '8'
  |AskForMode


Procedure AskForMode
var St V
   DrawBox (Min(ScreenWidth / 2 - 2,ScreenWidth - 26), ScreenHeight / 2 + 5, 26, 3)
   Write ' Enter Video Mode: '
   St = Readln
   V = Value St
   if V = 0
      EraseTopWindow
      Return
   endif
   SetMode(V)
EndProc


Procedure SetMode (V)
   TextMode(V)
   ExitMenu
EndProc


Procedure DrawBar
   TextColor LCyan Blue
   ClearLine 'Í'
   TextColor Yellow Blue
EndProc